Microsoft Visual Basic: Colour Combo Box

Why not use a ColorDialog ?

Just enter dialogs into the Help search and you should find them all.

Basic use as follows:

Dim CD As New ColorDialog
Dim SelectedColor As Color
If CD.ShowDialog() = Windows.Forms.DialogResult.OK Then
SelectedColor = CD.Color
End If

HI,

Is there a colour box which displays the list you get in visual sudio when you type

color. Aqua blue
Brick red
etc

?

Thanks,

ANdy

^^^ Dave299 beat me to it, but I'll post my code anyway:

---

Public Class Form1

Private WithEvents zColorCombobox1 As New xxColorCombobox
Private WithEvents zColorCombobox2 As New xxColorCombobox
Private WithEvents zColorCombobox3 As New xxColorCombobox

Private Sub Form1_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load

zColorCombobox1.ColorsToShow = xxColorCombobox.KnownColorsToShow.SystemColorsOnly
zColorCombobox1.Dock = DockStyle.Top
Me.Controls.Add(zColorCombobox1)

zColorCombobox2.ColorsToShow = xxColorCombobox.KnownColorsToShow.NamedWebColorsOnly
zColorCombobox2.Dock = DockStyle.Bottom
Me.Controls.Add(zColorCombobox2)

zColorCombobox3.ColorsToShow = xxColorCombobox.KnownColorsToShow.All
zColorCombobox3.BackColor = Color.FromArgb(64, 64, 64)
zColorCombobox3.ForeColor = Color.White
zColorCombobox3.Font = New Font("Tahoma", 8, FontStyle.Bold, GraphicsUnit.Point)
zColorCombobox3.Dock = DockStyle.Top
Me.Controls.Add(zColorCombobox3)

End Sub

Private Sub zColorComboboxes_SelectedIndexChanged(ByVal sender As Object, ByVal e As System.EventArgs) Handles zColorCombobox1.SelectedIndexChanged, zColorCombobox2.SelectedIndexChanged, zColorCombobox3.SelectedIndexChanged
Dim zColorCombobox As xxColorCombobox = sender
Me.BackColor = zColorCombobox.SelectedColor
End Sub
End Class

Public Class xxColorCombobox
Inherits System.Windows.Forms.ComboBox

Public Enum KnownColorsToShow
All = 0
SystemColorsOnly = 1
NamedWebColorsOnly = 2
End Enum

Private zSelectedColor As Color = Color.AliceBlue
Private zColorsToShow As KnownColorsToShow = KnownColorsToShow.All
Private zIncludeKnownColor_Transparent As Boolean = False

Sub New()
With Me
.Parent = Nothing
.DrawMode = Windows.Forms.DrawMode.OwnerDrawVariable
.DropDownStyle = ComboBoxStyle.DropDownList
End With
Me.ColorsToShow = KnownColorsToShow.All
End Sub

Private Sub xxColorCombobox_ParentChanged(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.ParentChanged
Me.Update_ColorList()
End Sub

<System.ComponentModel.Category("Appearance")> Public Property SelectedColor() As Color
Get
Return zSelectedColor
End Get
Private Set(ByVal value As Color)
Try
zSelectedColor = value
Catch ex As Exception
End Try
End Set
End Property

<System.ComponentModel.Category("Appearance")> Public Property ColorsToShow() As KnownColorsToShow
Get
Return zColorsToShow
End Get
Set(ByVal value As KnownColorsToShow)
zColorsToShow = value
Update_ColorList()
End Set
End Property

<System.ComponentModel.Category("Behavior")> Public Property IncludeKnownColor_Transparent() As Boolean
Get
Return zIncludeKnownColor_Transparent
End Get
Set(ByVal value As Boolean)
zIncludeKnownColor_Transparent = value
End Set
End Property

Private Sub Update_ColorList()
Try
Me.Items.Clear()
Dim zArrayList As New ArrayList
zArrayList.Clear()
For Each zKnownColor As KnownColor In [Enum].GetValues(GetType(KnownColor))
If zKnownColor = KnownColor.Transparent AndAlso zIncludeKnownColor_Transparent = False Then Continue For
Select Case zColorsToShow
Case KnownColorsToShow.All
zArrayList.Add(zKnownColor.ToString)
Case KnownColorsToShow.NamedWebColorsOnly
If Color.FromKnownColor(zKnownColor).IsSystemColor = False Then
zArrayList.Add(zKnownColor.ToString)
End If
Case KnownColorsToShow.SystemColorsOnly
If Color.FromKnownColor(zKnownColor).IsSystemColor = True Then
zArrayList.Add(zKnownColor.ToString)
End If
End Select
Next
zArrayList.TrimToSize()
zArrayList.Sort()
Me.Items.AddRange(zArrayList.ToArray)
Me.SelectedIndex = 0
Catch ex As Exception
End Try
End Sub

Private Sub xxColorCombobox_DrawItem(ByVal sender As Object, ByVal e As System.Windows.Forms.DrawItemEventArgs) Handles Me.DrawItem
Try
e.DrawBackground()
Dim zColor As Color = Color.FromKnownColor([Enum].Parse(GetType(KnownColor), Me.Items(e.Index)))
Dim zColorName As String = Color.FromKnownColor([Enum].Parse(GetType(KnownColor), Me.Items(e.Index))).ToKnownColor.ToString
Dim zLGB As New Drawing2D.LinearGradientBrush(e.Bounds, Me.BackColor, zColor, Drawing2D.LinearGradientMode.Horizontal)
Dim zBrush As New SolidBrush(Me.ForeColor)
e.Graphics.FillRectangle(zLGB, e.Bounds)
e.Graphics.DrawString(zColorName, Me.Font, zBrush, e.Bounds.X, e.Bounds.Y)
e.DrawFocusRectangle()
Catch ex As Exception
End Try
End Sub

Private Sub xxColorCombobox_SelectedIndexChanged(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.SelectedIndexChanged
Try
If Me.SelectedItem Is Nothing Then Exit Sub
Me.SelectedColor = Color.FromKnownColor([Enum].Parse(GetType(KnownColor), Me.Items(Me.SelectedIndex)))
Catch ex As Exception
End Try
End Sub

Private Sub xxColorCombobox_SystemColorsChanged(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.SystemColorsChanged
Me.Update_ColorList()
End Sub
End Class

Dave299 wrote:

Very nice - I'd been trying to think of an elegant way to make sure the text would always be readable.

Thanks, Dave - I ? gradients, it's a cheap effect but they never go out of style

Thanks - it's pretty much the same as Dave's code, though

The xxColorCombobox class that I created (under the Form1 Class code) can be used like a normal combobox. If you're using VB2005, then build or run the solution once, and then you should see 'xxColorCombobox' in the toolbox like the other controls (it will be in a section that is named after your project).

Or you can create it via code, like you would with a normal combobox. xxColorCombobox has a .SelectedColor property that gives you the color that is currently selected in the ColorCombobox:

Private aNewCombo as New xxColorCombobox
Private aColor as Color = aNewCombo.SelectedColor

And you can use the .ColorsToShow property to limit the colors to SystemColors or NamedWebColors only (or All of them). The SelectedIndexChanged event can be used to keep your color-variable up to date with the color you selected in the combobox:

Private Sub aNewCombo_SelectedIndexChanged(ByVal sender As Object, ByVal e As System.EventArgs) Handles aNewCombo.SelectedIndexChanged

Dim zColorCombobox As xxColorCombobox = sender
aColor = zColorCombobox.SelectedColor

End Sub

---

EDIT: Hmmm... for some reason, it's showing the NamedWebColors twice. Gonna look into that.

Thanks, Tall Dude - note that there seems to be a little problem with it at the moment, though - I think the ArrayList is causing the list to double (so all entries appear twice), but haven't gotten to the bottom of it yet - i'll edit the fixed code into my earlier reply, as soon as I figure out where the doubling is happening.

EDIT: The list only doubles when the control is added at designtime, so I'm not sure I'll be able to figure it out